Labs

package org.libspark.utils 
{
    import flash.external.ExternalInterface;
    import flash.utils.getQualifiedClassName;
 
    /**
     * <p>Data????????????perl?Data::Dumper???????
     * ???????????Object, Array, Number, String, Boolean???
     * XML?????????????????
     * ??????FireBug?console???????????????????????
     * debug, info, warn, error ???????????????</p>
     * <listing>
     * package {
     *    import org.libspark.utils.Dumper;
     *    public Class Hoge {
     *        var test:Object = { a:'hoge', b:'fuga'};
     *        Dumper.debug(test);
     *        trace(Dumper.toString(test));
     *    }
     *    // output
     *         $var0 = {
     *                     'a' => 'hoge',
     *                     'b' => 'fuga',
     *                 }
     *     
     * }</listing>
     * @author dealforest
     * @version 0.102
     */
 
    public class Dumper {
 
        private static const INDENT:String = "    ";
        /*
         * @default 4tab
        */
        private static var _dumpString:String = "";
 
        /**
         * ????????????????????
         *
         * @param args ???????(????)
         * @return _txt ??????????????????
         */
        public static function toString(... args):String {
            var _txt:String = _dumpString = '';
            for (var a:String in args)
                _txt += parse(args[a]);
            return _txt;
        }
 
        /**
         * FireBug???????'debug'?????
         *
         * @param args ???????(????)
         */
        public static function debug(... args):void {
            if (!ExternalInterface.available) return;
 
            var _txt:String = _dumpString = '';
            for (var a:String in args)
                _txt += parse(args[a]);
            //interim action for IE
            ExternalInterface.call('function (txt) { try { console.log(txt); } catch (e) {}; }', _txt);
        }
 
        /**
         * FireBug???????'info'?????
         *
         * @param args ???????(????)
         */
        public static function info(... args):void {
            if (!ExternalInterface.available) return;
 
            var _txt:String = _dumpString = '';
            for (var a:String in args)
                _txt += parse(args[a]);
            //interim action for IE
            ExternalInterface.call('function (txt) { try { console.info(txt); } catch (e) {}; }', _txt);
        }
 
        /**
         * FireBug???????'warn'?????
         *
         * @param args ???????(????)
         */
        public static function warn(... args):void {
            if (!ExternalInterface.available) return;
 
            var _txt:String = _dumpString = '';
            for (var a:String in args)
                _txt += parse(args[a]);
            //interim action for IE
            ExternalInterface.call('function (txt) { try { console.warn(txt); } catch (e) {}; }', _txt);
        }
 
        /**
         * FireBug???????'error'?????
         *
         * @param arg ???????(????)
         */
        public static function error(... args):void {
            if (!ExternalInterface.available) return;
 
            var _txt:String = _dumpString = '';
            for (var a:String in args)
                _txt += parse(args[a]);
            //interim action for IE
            ExternalInterface.call('function (txt) { try { console.error(txt); } catch (e) {}; }', _txt);
        }
 
        /**
         * ????????????????????
         *
         * @param arg ???????(??????1?)
         * @return ?????????????
         * @private
         */
        public static function parse(arg:*):String {
            var argIndent:String = ('$var'+ ' = ');
            _dumpString += argIndent;
            inspect(arg, argIndent.replace(/./g, ' '));
            _dumpString += '\n';
           return _dumpString;
        }
 
        /**
         * ?????????????????????
         *
         * @param arg ???????(??????1?)
         * @param indent ????????
         * @private
         */
        private static function inspect(arg:*, indent:String):void {
            var bracket:Object;
 
            switch (getQualifiedClassName(arg)) {
                case 'Object':
                    bracket = {start: '{', end: '}'};
                case 'Array':
                    bracket ||= {start: '[', end: ']'};
                    _dumpString += bracket.start + '\n';
                    recursion(arg, indent + INDENT);
                    _dumpString += (indent +bracket.end);
                    break;
                default:
                    _dumpString += format(arg, indent, true);
            }
        }
 
        /**
         * ?????????????????
         *
         * @param arg ???????(??????1?)
         * @param indent ????????
         * @private
         */
        private static function recursion(arg:*, indent:String):void {
            for (var index:String in arg) {
                var tmp:* = arg[index];
                var className:String = getQualifiedClassName(tmp);
                var bracket:Object;
 
                switch(className) {
                    case 'Object':
                        bracket = {start: '{', end: '}'};
                    case 'Array':
                        bracket ||= {start: '[', end: ']'};
                        var str:String = (getQualifiedClassName(arg) == 'Object')
                            ? '\'' + index + '\' => ' : '';
                        var indent_str:String = str.replace(/./g, ' ');
 
                        _dumpString += (indent + str + bracket.start + "\n");
                        recursion(tmp, indent + indent_str + INDENT);
                        _dumpString += (indent + indent_str + bracket.end + ",");
                        break;
                    default:
                        _dumpString += format(tmp, indent, false, arg, index);
                }
                _dumpString += "\n";
            }
        }
 
        /**
         * ??????????????????
         *
         * @param target ?????Object
         * @param indent ????????
         * @param braket ,??????????
         * @param parent ?????Object
         * @param index Object?key
         * @return ???????????????
         * @private
         */
        private static function format(target:Object, indent:String, bracket:Boolean, parent:* = null, index:String = null):String {
            var className:String = getQualifiedClassName(target);
            var str:String = "";
 
            if (getQualifiedClassName(parent) == 'Object')
                return indent +  "\'" + index + "\'" + " => " + target + (bracket ? '' : ',');
 
            switch (className) {
                case 'String':
                    return (bracket)
                        ? "\'" + target + "\'"
                        : indent + "\'" + target + "\',";
 
                case 'Array':
                case 'int':
                case 'uint':
                case 'Number':
                case 'Boolean':
                    return (bracket)
                        ? target.toString()
                        : indent + target.toString() + ",";
                default:
                    return 'don\'t analyze';
            }
        }
    }
}

 
function getRandomPointInTriangle (A:Point,B:Point,C:Point):Point {
 
	//P = aA + bB + cC
	//@see http://www.cgafaq.info/wiki/Random_Point_In_Triangle
 
	var a:Number = Math.random();
	var b:Number = Math.random();
 
	if (a + b > 1) {
		a = 1-a;
		b = 1-b;
	}
 
	var c:Number = 1-a-b;
 
	var rndX:Number = (a*A.x)+(b*B.x)+(c*C.x);
	var rndY:Number = (a*A.y)+(b*B.y)+(c*C.y);
 
	return new Point(rndX,rndY);
}
 
 
var triangleHeight:uint = 150;
var triangleShape:Shape = new Shape();
triangleShape.graphics.lineStyle(1,0xff0000);
triangleShape.graphics.moveTo(triangleHeight/2, 5);
triangleShape.graphics.lineTo(triangleHeight, triangleHeight+5);
triangleShape.graphics.lineTo(0, triangleHeight+5);
triangleShape.graphics.lineTo(triangleHeight/2, 5);
addChild(triangleShape);
 
 
var p1:Point = new Point(triangleHeight/2, 5);
var p2:Point = new Point(triangleHeight, triangleHeight+5);
var p3:Point = new Point(0, triangleHeight+5);
 
//
//
//
//
 
var source:BitmapData = new BitmapData(triangleHeight,triangleHeight,true,0);
var bitmap:Bitmap = new Bitmap(source);
 
var sprite:Sprite = new Sprite();
sprite.addChild(bitmap);
addChild(sprite);
 
 
source.fillRect(source.rect,0);
source.lock();
 
for (var i:int = 0;i<50;i++) {
	var p:Point = getRandomPointInTriangle(p1,p2,p3);
	source.setPixel32(p.x,p.y,0xffff0000);
}
 
source.unlock();

 
function alwaysOnTop_handler(e:Event):void {
	//make this child always on top!
	parent.addChild(this);
}
 
function added_handler(e:Event):void {
	parent.addEventListener(Event.ADDED, alwaysOnTop_handler, false, 0, true);
}
 
addEventListener(Event.ADDED_TO_STAGE, added_handler, false, 0, true)

 
function isValid(str:String):Boolean {
        var regExp:RegExp = /\b(badword|nastyWord)\b/i;
	var _isValid:Boolean = !regExp.test(str);
        return _isValid;
}
 
var _inValidMessage = "this is a example for a bad badword it's really nasty";
var _validMessage = "Hello Word!";
 
trace(isValid(_inValidMessage)) //false
trace(isValid(_validMessage))//true